レジストリ

'日付によって消費税率を変更させるプログラム（標準モジュール）

'----------------------------------------------------*/

Option Explicit

Public Const gcstrAppName As String = "ＶＢＡ解説"

Public Function setTaxRate(sglTaxRate As Single, Optional dtTargetDate As Date = 1) As String
    RegS "TAX_RATE", CStr(dtTargetDate), CStr(sglTaxRate)
    setTaxRate = "完了しました"
End Function

'第三引数（intFraction)⇒0（切捨て）1（切り上げ）2（四捨五入）
Public Function TaxEx(price As Single, dtTargetDate As Date, Optional intFraction As Integer = 0) As Integer
    '前処理
    TaxEx = price

    Dim varResult As Variant

    'バリアント型配列にレジストリの値を格納
    varResult = GetAllSettings(gcstrAppName, "TAX_RATE")

    Dim i As Integer
    Dim dtDate As Date
    Dim prevDate As Date
    For i = 0 To UBound(varResult)
    '日付を一時的に格納
        dtDate = varResult(i, 0)

        If dtTargetDate >= dtDate Then
        '前回日付より経過しているかどうか判定
            If dtDate > prevDate Then
                '計算
                '端数処理（blnFraction）
                    If intFraction = 0 Then '切り捨て
                        TaxEx = Int(price * varResult(i, 1))
                    ElseIf intFraction = 1 Then '切り上げ
                        TaxEx = Int(price * varResult(i, 1) + 0.99)
                    Else '四捨五入
                        TaxEx = Int(price * varResult(i, 1) + 0.5)
                    End If

                    prevDate = dtDate
            End If
    End If
    Next

End Function

'レジストリセーブ
Sub RegS(strSection As String, strKey As String, strSetting As String)
    SaveSetting gcstrAppName, strSection, strKey, strSetting
End Sub

'レジストリ読み込み（一応作成）
Function RegG(strSection As String, strKey As String) As String
    RegG = GetSetting(gcstrAppName, strSection, strKey)
End Function